Analysis of the Simple OTA

Small-Signal Analysis

Simplified differential analysis

Quit

eq1={+Gm1*Vid/2-Gms1*V1-Gm1*Vid/2-Gms1*V1==0,
Gm2*V2==Gm1*Vid/2-Gms1*V1,
Gm2*V2==Iout-Gm1*Vid/2-Gms1*V1}

sol1=Solve[eq1,{Iout,V1, V2}]

Full analysis (perfect matching)

Quit

Neglecting all the output conductances and writing the KCL equations results in

eq1={Gm1a*VG1a-Gms1a*V1+Gm1b*VG1b-Gms1b*V1==(G1+s*C1)*V1,
(Gm2+s*C2)*V2==Gm1a*VG1a-Gms1a*V1,
Gm2b*V2==Iout+Gm1b*VG1b-Gms1b*V1,
Vinp==VG1a,
Vinn==VG1b}

sol1=Solve[eq1,{Iout,V1, V2, VG1a, VG1b}]

sol1[[1,1]]

Iout=Simplify[Iout /. sol1[[1,1]]]

Iout1=Collect[(Iout /. {Vinp->Vic+Vid/2,Vinn->Vic-Vid/2}),{Vid,Vic},Factor]

Iod=Simplify[Iout1 /. {Vic->0}]

Iodmatched=Simplify[Iod /. {Gm1a->Gm1, Gm1b->Gm1, Gms1a->Gms1,Gms1b->Gms1,Gm2a->Gm2,Gm2b->Gm2}]

Ymd=Simplify[Iodmatched/Vid]

Ymd0=Simplify[Ymd /. s->0]

Ymdinf=Limit[Ymd,s->Infinity]

Ymd=Simplify[Ymd /. C2->Gm2*tau2]

Ioc=Simplify[Iout1 /. {Vid->0}]

Iocmatched=Simplify[Ioc /. {Gm1a->Gm1, Gm1b->Gm1, Gms1a->Gms1,Gms1b->Gms1,Gm2a->Gm2,Gm2b->Gm2}]

Ymc=Simplify[Iocmatched/Vic]

Ymc0=Simplify[Ymc /. s->0]

Ymcinf=Limit[Ymc,s->Infinity]

Ymc=Simplify[Ymc /. G1->0]

Ymc=Simplify[Ymc /. {C1->Gms1*2*tau1,C2->Gm2*tau2}]

CMRR=Simplify[Ymd/Ymc]

Noise analysis

Quit

eq1={-Gms1a*V1+In1a +In1b-Gms1b*V1==G1*V1+In3,
Gm2a*V2+In2a== -Gms1a*V1+In1a,
Gm2b*V2+In2b== Inout -Gms1b*V1+In1b}

sol1=Solve[eq1,{Inout,V1,V2}]

sol1[[1,1]]

Inout=Inout /. sol1[[1,1]]

Inout=Simplify[Inout /. {Gms1a->Gms1,Gms1b->Gms1, Gm2a->Gm2,Gm2b->Gm2}]

Input referred noise resistance

Gnout=2*(Gn1+Gn2)

Rnin=Gnout/Gm1^2

Input-referred thermal noise resistance

Rninth=Simplify[Rnin /. {Gn1->gamman1*Gm1,Gn2->gamman2*Gm2}]

Expand[%]

etath=gamman2/gamman1*Gm2/Gm1

Rninth1=2*gamman1/Gm1*(1+etath)

Simplify[Rninth1-Rninth]

Input-referred flicker noise resistance

Rninfl=Simplify[Rnin /. {Gn1->Gm1^2*rhon/(f*W1*L1),Gn2->Gm2^2*rhop/(f*W2*L2)}]

Rnf1=2*rhon/(f*W1*L1)

etafl=Simplify[Rninfl/Rnf1-1]

Rninfl1=Rnf1*(1+etafl)

Simplify[Rninfl1-Rninfl]