Constrained minimization using Lagrange multipliers

Function

A={{3,2},{2,6}};
ϕ[x_,y_]:=0.5{x,y}.A.{x,y}-{x,y}.{3,-1}

ϕ[x,y]//Expand

g1=Plot3D[ϕ[x,y],{x,-5,5},{y,-5,5}]

ContourPlot[ϕ[x,y],{x,-5,5},{y,-5,5}]

Global minimum

Minimize[ϕ[x,y],{x,y}]

xmin=Minimize[ϕ[x,y],{x,y}][[2]]

g2=ListPointPlot3D[{{x,y,ϕ[x,y]}}/.xmin]

Show[g1,g2]

Constraint

h1=ParametricPlot3D[{Cos[θ],Sin[θ],0},{θ,-Pi,Pi}]

g3=ParametricPlot3D[{Cos[θ],Sin[θ],ϕ[Cos[θ],Sin[θ]]},{θ,-Pi,Pi}]

Show[g3,h1]

Show[g1,g3,g2]

Contrained minimization (without Lagrage multipliers)

Minimize[ϕ[Cos[θ],Sin[θ]],θ]

θmin=Minimize[ϕ[Cos[θ],Sin[θ]],θ][[2]]

pmin=ListPointPlot3D[{{Cos[θ],Sin[θ],ϕ[Cos[θ],Sin[θ]]}}/.θmin,PlotStyle->{Red,Thick}]

Show[g1,g3,g2,pmin]

Contrained minimization (with Lagrage multipliers)

D[x^2+y^2,{{x,y}}]

g[x_,y_]:=x^2+y^2

D[ϕ[x,y]+λ g[x,y],{{x,y}}]

Solve[{D[ϕ[x,y]+λ g[x,y],{{x,y}}]==0,g[x,y]==1},{x,y,λ}]

{Cos[θ],Sin[θ]}/.θmin

We found the minimum (together with the other critical points) using the Lagrange multipliers method!

Homework

1. Reproduce the intuitive explanation (better if you can explain it to someone)
2. Try to find another characterization of the constrained minimum (with parametrization ?)
3. Ideas o Quantum Chemistry, Piela, Appendix on Variational Principle
4. Can you come up with an intuitive explanation, on R3 as the domain (e.g., temperature function), of a constrained minimization?
5. Can you extend your intuitive explanation to two constraints?(Why the gradient of the function is a linear combination of the gradient of the two constraints!?)